# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils cmake-utils games subversion

ESVN_REPO_URI="https://holdingnuts.svn.sourceforge.net/svnroot/holdingnuts/trunk"
ESVN_PROJECT="holdingnuts-snapshot"

DESCRIPTION="An open source poker client and server"
HOMEPAGE="http://www.holdingnuts.net/"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa debug dedicated sqlite"

RDEPEND="
	dev-db/sqlite:3
	!dedicated? (
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
		alsa? ( >=media-libs/libsdl-1.2.10[alsa] )
	)"

DEPEND="${RDEPEND}
	>=dev-util/cmake-2.6.3"


pkg_setup() {
	ewarn
	ewarn "This is a subversion snapshot of HoldingNuts, so no functionality is"
	ewarn "guaranteed! It's possible that this snapshot doesn't even build."
	ewarn
}

src_unpack() {
	subversion_src_unpack
	cd "${S}"
}

src_configure() {
	local mycmakeargs="$(cmake-utils_use_enable alsa AUDIO)
		$(cmake-utils_use_enable !dedicated CLIENT)
		$(cmake-utils_use_enable debug DEBUG)
		$(cmake-utils_use_enable sqlite SQLITE)"

	mycmakeargs="${mycmakeargs}
		-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
		-DCMAKE_DATA_PATH=${GAMES_DATADIR}"

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if ! use dedicated ; then
		doman docs/${PN}.6
	fi

	dodoc docs/protocol_spec.txt
	doman docs/${PN}-server.6

	prepgamesdirs
}